作者：未知     来源：网络

一体化红外线接收器是一种集红外线接收和放大于一体，不需要任何外接元件，就能完成从红外线接收到输出与TTL电平信号兼容的所有工作，而体积和普通的塑封三极管大小一样，它适合于各种红外线遥控和红外线数据传输。

ORG 0000H
START:MOV P0,#0FFH
MOV P1,#0FFH
MOV P2,#0FFH
MOV P3,#0FFH
JNB P3.2,$;等待遥控信号出现
MOV R6,#10
SB: ACALL YS1;调用882微秒延时子程序
JB P3.2,START;延时882微秒后判断P3.2脚是否出现高电平如果有就退出解码程序
DJNZ R6, SB;重复10次，目的是检测在8820微秒内如果出现高电平就退出解码程序
;以上完成对遥控信号的9000微秒的初始低电平信号的识别。
JNB P3.2, $ ;等待高电平避开9毫秒低电平引导脉冲
ACALL YS2 ;延时4.74毫秒避开4.5毫秒的结果码
MOV R1,#1AH ;设定1AH为起始RAM区
MOV R2,#4
PP: MOV R3,#8
JJJJ: JNB P3.2,$;等待地址码第一位的高电平信号
LCALL YS1;高电平开始后用882微秒的时间尺去判断信号此时的高低电平状态
MOV C,P3.2;将P3.2引脚此时的电平状态0或1存入C中
JNC UUU;如果为0就跳转到UUU
JB P3.2,$;如果为1就等待高电平信号结束
UUU: MOV A,@R1;将R1中地址的给A
RRC A;将C中的值0或1移入A中的最低位
MOV @R1,A;将A中的数暂时存放在R1中
DJNZ R3,JJJJ;接收地址码的高8位
INC R1;对R1中的值加1，换成下一个RAM
DJNZ R2,PP ;接收完16位地址码和8位数据码和8位数据反码，存放在1AH/1BH/1CH/1DH的RAM中
;以下对代码是否正确和定义进行识别
MOV A,1AH;比较高8位地址码
XRL A,#00000000B ;判断1AH的值是否等于00000000，相等的话A为0
JNZ EXIT;如果不相等说明解码失败退出解码程序
MOV A,1BH;比较低8位地址
XRL A,#11111111B ;再判断高8位地址是否正确
JNZ EXIT;如果不相等说明解码失败退出解码程序
MOV A,1CH;比较数据码和数据反码是否正确?
CPL A
XRL A,1DH ;将1CH的值取反后和1DH比较 不同则无效丢弃，核对数据是否准确
JNZ EXIT;如果不相等说明解码失败退出解码程序
CLR P2.7;解码成功发光二极管点亮指示!
AJMP BIJIAO

;判断在118毫秒内是否有连发码
AA:MOV R1,#25
XX:ACALL YS2
JNB P3.2,HH;跳转到判断连发代码是否正确的程序段
DJNZ R1,XX
EXIT: MOV P0,#0FFH;对所有端口清零
MOV P1,#0FFH
MOV P2,#0FFH
MOV P3,#0FFH
AJMP START

;连发码判断程序段-----------
HH:MOV R6,#4
S: ACALL YS1;调用882微秒延时子程序
JB P3.2,EXIT;延时882微秒后判断P3.2脚是否出现高电平如果有就退出解码程序
DJNZ R6, S;重复4次，目的是确认连发码的低电平信号波形
JNB P3.2, $ ;等待高电平
AJMP AA

BIJIAO:MOV A,1CH;按键数值判断执行
CJNE A,#00000101B,TT1
CPL P0.0
TT1: CJNE A,#00000100B,TT2
CPL P0.1
TT2: CJNE A,#00010000B,T3
CPL P0.2
T3: CJNE A,#01001101B,T5
CPL P0.3
T5: CJNE A,#01001110B,T6
CPL P0.4
T6: CJNE A,#01001100B,T7
CPL P0.5
T7: CJNE A,#00001001B,T8
CPL P0.6
T8: CJNE A,#00011101B,T9
CPL P0.7
T9: CJNE A,#00011111B,T10
CPL P2.6
T10: CJNE A,#00001101B,T11
CPL P2.5
T11: CJNE A,#00011001B,T12
CPL P2.4
T12: CJNE A,#00011011B,T13
CPL P2.3
T13: CJNE A,#00010001B,T14
CPL P2.2
T14: CJNE A,#00010101B,T15
CPL P2.1
T15: CJNE A,#00010111B,T16
CPL P2.0
T16: CJNE A,#00010010B,T17
CPL P1.0
T17: CJNE A,#00010110B,T18
CPL P1.1
T18: CJNE A,#01011110B,T19
CPL P1.2
T19: CJNE A,#01011101B,T20
CPL P1.3
T20: CJNE A,#01011100B,T21
CPL P1.4
T21: CJNE A,#01001111B,T22
CPL P1.5
T22: CJNE A,#00000001B,T23
CPL P1.6
T23: CJNE A,#00000011B,T24
CPL P1.7
T24: CJNE A,#00000000B,T25
CPL P3.0
T25: CJNE A,#00010100B,T26
CPL P3.1
T26: CJNE A,#00011110B,T27
CPL P3.3
T27: CJNE A,#00011010B,T28
CPL P3.4
T28: CJNE A,#00001111B,T29
CPL P3.5
T29: CJNE A,#00001010B,T30
CPL P3.6
T30: CJNE A,#00001110B,OK
CPL P3.7
OK:AJMP AA
YS1: MOV R4,#20 ;延时子程序1，精确延时882微秒
D1: MOV R5,#20
DJNZ R5,$
DJNZ R4,D1
RET
YS2: MOV R4,#10 ;延时子程序2，精确延时4740微秒
D2: MOV R5,#235
DJNZ R5,$
DJNZ R4,D2
RET
END