arm2410和44b0启动文件分析（很全面）_ARM/CPLD/综合_微控实验网！51单片机AVR单片机教程站 www.mcusy.cn

当前位置：首页 > ARM/CPLD/综合 > 详细内容

arm2410和44b0启动文件分析（很全面）

发布时间：2009/7/22 阅读次数：838 字体大小: 【小】【中】【大】

工程里面的头文件 2410Init.s包括了板子上电后的初始话，具体有几个步骤：

讲述S3C2410启动程序设计

1. 屏蔽所有中断，关看门狗。

2. 根据工作频率设置PLL寄存器

3. 初始化存储控制相关寄存器

4. 初始化各模式下的栈指针

5. 设置缺省中断处理函数

6. 将数据段拷贝到RAM中，将零初始化数据段清零

7. 跳转到C语言Main入口函数中

要看懂这个头文件是比较难的，我跟DVD视频的教程看了两遍，弄懂了一些，视频上讲的是 ARM7 S3C44B0的 Init.s 但我觉得和2410的差不多。我将这个程序注释了一下。可能有些地方不是很正确，只提供参考。

;=========================================
; NAME: 2410INIT.S
; DESC: C start up codes
; Configure memory, ISR ,stacks
; Initialize C-variables
; HISTORY:
; 2002.02.25:kwtark: ver 0.0
; 2002.03.20: purnnamu: Add some functions for testing STOP,POWER_OFF mode
; 2002.04.10:SJS:sub interrupt disable 0x3ff -> 0x7ff
; 2002.11.29:Kong: DCD BANKSIZE Resiger 0x32 -> 0xb2 (ARM core burst enable)
;=========================================

INCLUDE option.inc
INCLUDE memcfg.inc
INCLUDE 2410addr.inc

BIT_SELFREFRESH EQU (1<<22)

;下面是对arm处理器模式寄存器对应值的常数定义，arm处理器中有一个CPSR程序状态寄存器它的后五位决定目前的处理器模式
; pre-defined constants
USERMODE EQU 0x10
FIQMODE EQU 0x11
IRQMODE EQU 0x12
SVCMODE EQU 0x13
ABORTMODE EQU 0x17
UNDEFMODE EQU 0x1b
MODEMASK EQU 0x1f
NOINT EQU 0xc0

;The location of stacks
UserStack EQU (_STACK_BASEADDRESS-0x3800) ;0x33ff4800 ~
SVCStack EQU (_STACK_BASEADDRESS-0x2800) ;0x33ff5800 ~
UndefStack EQU (_STACK_BASEADDRESS-0x2400) ;0x33ff5c00 ~
AbortStack EQU (_STACK_BASEADDRESS-0x2000) ;0x33ff6000 ~
IRQStack EQU (_STACK_BASEADDRESS-0x1000) ;0x33ff7000 ~
FIQStack EQU (_STACK_BASEADDRESS-0x0) ;0x33ff8000 ~

;check if tasm.exe is used.
;arm处理器有两种工作状态 1.arm:32位这种工作状态下执行字对准的arm指令 2.Thumb:16位这种工作状;态执行半字对准的Thumb指令
;因为处理器分为16位 32位两种工作状态程序的编译器也是分16位和32两种编译方式所以下面的程序用;于根据处理器工作状态确定编译器编译方式
;code16伪指令指示汇编编译器后面的指令为16位的thumb指令
;code32伪指令指示汇编编译器后面的指令为32位的arm指令
;这段是为了统一目前的处理器工作状态和软件编译方式（16位编译环境使用tasm.exe编译
;Check if tasm.exe(armasm -16 ...@ADS 1.0) is used.
GBLL THUMBCODE
[ {CONFIG} = 16 ;if config==16 这里表示你的目前处于领先地16位编译方式
THUMBCODE SETL {TRUE};设置THUMBCODE 为 true
CODE32;转入32位编译模式
| ;else
THUMBCODE SETL {FALSE};设置THUMBCODE 为 false
]

MACRO
MOV_PC_LR
[ THUMBCODE
bx lr
|
mov pc,lr
]
MEND

MACRO
MOVEQ_PC_LR
[ THUMBCODE
bxeq lr
|
moveq pc,lr
]
MEND

;注意下面这段程序是个宏定义很多人对这段程序不理解我再次强调这是一个宏定义所以大家要注意了
;下面包含的HandlerXXX HANDLER HandleXXX将都被下面这段程序展开
;这段程序用于把中断服务程序的首地址装载到pc中，有人称之为“加载程序”。
;本初始化程序定义了一个数据区（在文件最后），34个字空间，存放相应中断服务程序的首地址。每个字
;空间都有一个标号，以Handle***命名。
;在向量中断模式下使用“加载程序”来执行中断服务程序。
;这里就必须讲一下向量中断模式和非向量中断模式的概念
;向量中断模式是当cpu读取位于0x18处的IRQ中断指令的时候，系统自动读取对应于该中断源确定地址上的;
;指令取代0x18处的指令，通过跳转指令系统就直接跳转到对应地址
;函数中节省了中断处理时间提高了中断处理速度标例如 ADC中断的向量地址为0xC0,则在0xC0处放如下
;代码：ldr PC,=HandlerADC 当ADC中断产生的时候系统会
;自动跳转到HandlerADC函数中
;非向量中断模式处理方式是一种传统的中断处理方法，当系统产生中断的时候，系统将interrupt
; pending寄存器中对应标志位置位然后跳转到位于0x18处的统一中断
;函数中该函数通过读取interrupt pending寄存器中对应标志位来判断中断源并根据优先级关系再跳到
;对应中断源的处理代码中
MACRO
$HandlerLabel HANDLER $HandleLabel
;HandlerLabel为中断服务入口地址
$HandlerLabel
sub sp,sp,#4 ; Decrement sp(to store jump address)
;将要使用的r0寄存器入栈
stmfd sp!,{r0} ; pUSH the work register to stack(lr doest push because it return to original address)
ldr r0,=$HandleLabel; load the address of HandleXXX to r0
ldr r0,[r0] ; load the contents(service routine start address) of HandleXXX
;将对应的中断函数首地址入栈
str r0,[sp,#4] ;store the contents(ISR) of HandleXXX to stack
;将中断函数首地址出栈放入程序指针中系统将跳转到对应中断处理函数
ldmfd sp!,{r0,pc} ; pOP the work register and pc(jump to ISR)
MEND

;一个arm由RO,RW,ZI三个断组成其中RO为代码段，RW是已经初始化的全局变量，ZI是未初始化的全局变量
;（对于GNU工具对应的概念是TEXT ,DATA,BSS）bootloader
;bootloader要将RW段复制到ram中并将ZI段清零编译器使用下列段来记录各段的起始和结束地址
; |Image$$RO$$Base| ; RO段起始地址
; |Image$$RO$$Limit| ; RO段结束地址加1
; |Image$$RW$$Base| ; RW段起始地址
; |Image$$RW$$Limit| ; RW段结束地址加1
; |Image$$ZI$$Base| ; ZI段起始地址
; |Image$$ZI$$Limit| ; ZI段结束地址加1
;这些标号的值是通过编译器的设定来确定的如编译软件中对ro-base和rw-base的设定，例如 ro-;base=0xc000000 rw-base=0xc5f0000
IMPORT |Image$$RO$$Limit| ; End of ROM code (=start of ROM data)
IMPORT |Image$$RW$$Base| ; Base of RAM to initialise
IMPORT |Image$$ZI$$Base| ; Base and limit of area
IMPORT |Image$$ZI$$Limit| ; to zero initialise

IMPORT Main ; The main entry of mon program

AREA Init,CODE,READONLY
;异常中断矢量表（每个表项占4个字节）下面是中断向量表一旦系统运行时有中断发生即使移植了操作;系统如linux 处理器已经把控制权交给了操作系统一旦发生中断处理器还是会跳转到从0x0开始
;中断向量表中某个中断表项（依据中断类型）开始执行
;具体中断向量布局请参考s3c44b0 spec 例如 adc中断向量为 0x000000c0下面对应表中第49项位置向量地址0x0+4*(49-1)=0x000000c0
ENTRY
;板子上电和复位后程序开始从位于0x0处开始执行硬件刚刚上电复位后程序从这里开始执行跳转到标?
;为ResetHandler处执行
;1)The code, which converts to Big-endian, should be in little endian code.
;2)The following little endian code will be compiled in Big-Endian mode.
; The code byte order should be changed as the memory bus width.
;3)The pseudo instruction,DCD cant be used here because the linker generates error.
;总线宽度判?
; DCD用于分配一段字内存单片，并用后面的伪指令初始化
;分配字节由expr 个数决定
ASSERT : DEF:ENDIAN_CHANGE
[ ENDIAN_CHANGE
ASSERT : DEF:ENTRY_BUS_WIDTH
[ ENTRY_BUS_WIDTH=32
b ChangeBigEndian ; DCD 0xea000007
]

[ ENTRY_BUS_WIDTH=16
andeq r14,r7,r0,lsl #20 ; DCD 0x0007ea00
]

[ ENTRY_BUS_WIDTH=8
streq r0,[r0,-r10,ror #1] ; DCD 0x070000ea
]
|
b ResetHandler
]
b HandlerUndef ;handler for Undefined mode
b HandlerSWI ;handler for SWI interrupt
b HandlerPabort ;handler for PAbort
b HandlerDabort ;handler for DAbort
b . ;reserved 0x14
b HandlerIRQ ;handler for IRQ interrupt
b HandlerFIQ ;handler for FIQ interrupt

;@0x20
b EnterPWDN
;大小端判断
ChangeBigEndian
;@0x24
[ ENTRY_BUS_WIDTH=32
DCD 0xee110f10 ;0xee110f10 => mrc p15,0,r0,c1,c0,0
DCD 0xe3800080 ;0xe3800080 => orr r0,r0,#0x80; //Big-endian
DCD 0xee010f10 ;0xee010f10 => mcr p15,0,r0,c1,c0,0
]
[ ENTRY_BUS_WIDTH=16
DCD 0x0f10ee11
DCD 0x0080e380
DCD 0x0f10ee01
]
[ ENTRY_BUS_WIDTH=8
DCD 0x100f11ee
DCD 0x800080e3
DCD 0x100f01ee
]
DCD 0xffffffff ;swinv 0xffffff is similar with NOP and run well in both endian mode.
DCD 0xffffffff
DCD 0xffffffff
DCD 0xffffffff
DCD 0xffffffff
b ResetHandler

;进入掉电模式功能
; 1. SDRAM 必须在自刷新模式.
; 2. 所有中断必须屏蔽 for SDRAM/DRAM self-refresh.
; 3. LCD 关闭for SDRAM/DRAM self-refresh.
; 4. The I-cache 可能需要开启.
; 5. The location of the following code may have not to be changed.

;void EnterPWDN(int CLKCON);
EnterPWDN
mov r2,r0 ;r2=rCLKCON
tst r0,#0x8 ; pOWER_OFF mode?
bne ENTER_POWER_OFF

ENTER_STOP
ldr r0,=REFRESH
ldr r3,[r0] ;r3=rREFRESH
mov r1, r3
orr r1, r1, #BIT_SELFREFRESH
str r1, [r0] ;Enable SDRAM self-refresh

mov r1,#16 ;wait until self-refresh is issued. may not be needed.
0 subs r1,r1,#1
bne %B0

ldr r0,=CLKCON ;enter STOP mode.
str r2,[r0]

mov r1,#32
0 subs r1,r1,#1 ;1) wait until the STOP mode is in effect.
bne %B0 ;2) Or wait here until the CPU&Peripherals will be turned-off
; Entering POWER_OFF mode, only the reset by wake-up is available.

ldr r0,=REFRESH ;exit from SDRAM self refresh mode.
str r3,[r0]

MOV_PC_LR

ENTER_POWER_OFF
;NOTE.
;1) rGSTATUS3 should have the return address after wake-up from POWER_OFF mode.

ldr r0,=REFRESH
ldr r1,[r0] ;r1=rREFRESH
orr r1, r1, #BIT_SELFREFRESH
str r1, [r0] ;Enable SDRAM self-refresh

mov r1,#16 ;Wait until self-refresh is issued,which may not be needed.
0 subs r1,r1,#1
bne %B0

ldr r1,=MISCCR
ldr r0,[r1]
orr r0,r0,#(7<<17) ;Make sure that SCLK0:SCLK->0, SCLK1:SCLK->0, SCKE=L during boot-up
str r0,[r1]

ldr r0,=CLKCON
str r2,[r0]

b . ;CPU will die here.

WAKEUP_POWER_OFF
;Release SCLKn after wake-up from the POWER_OFF mode.
ldr r1,=MISCCR
ldr r0,[r1]
bic r0,r0,#(7<<17) ;SCLK0:0->SCLK, SCLK1:0->SCLK, SCKE: l->H
str r0,[r1]

;Set memory control registers
ldr r0,=SMRDATA
ldr r1,=BWSCON ;BWSCON Address
add r2, r0, #52 ;End address of SMRDATA
0
ldr r3, [r0], #4
str r3, [r1], #4
cmp r2, r0
bne %B0

mov r1,#256
0 subs r1,r1,#1 ;1) wait until the SelfRefresh is released.
bne %B0

ldr r1,=GSTATUS3 ;GSTATUS3 has the start address just after POWER_OFF wake-up
ldr r0,[r1]
mov pc,r0

LTORG
;下面是具体的中断处理函数跳转的宏，通过上面的$HandlerLabel的宏定义展开后跳转到对应的中断处理;函数（对于向量中断）
HandlerFIQ HANDLER HandleFIQ
HandlerIRQ HANDLER HandleIRQ
HandlerUndef HANDLER HandleUndef
HandlerSWI HANDLER HandleSWI
HandlerDabort HANDLER HandleDabort
HandlerPabort HANDLER HandlePabort

;下面这段程序是用来处理非向量中断，具体判断I_ISPR中各位是否置1 置1表示目前此中断等待响应（每次只能有一位置1），从最高优先级中断位开始判断，检测到等待服务
;中断就将pc置为中断服务函数首地址
IsrIRQ
sub sp,sp,#4 ;预留返回指针的存储位置
stmfd sp!,{r8-r9}

ldr r9,=INTOFFSET
ldr r9,[r9];载入I_ISR
ldr r8,=HandleEINT0
add r8,r8,r9,lsl #2
ldr r8,[r8]
str r8,[sp,#8]
ldmfd sp!,{r8-r9,pc}

;=======
; ENTRY
;=======
;扳子上电和复位后程序开始从位于0x0执行b ResetHandler 程序从跳转到这里执行
;板子上电复位后执行几个步骤这里通过标号在注释中加1，2，3....标示标号表示执行顺序
;1.禁止看门狗屏蔽所有中断
ResetHandler
ldr r0,=WTCON ;watch dog disable
ldr r1,=0x0
str r1,[r0]

ldr r0,=INTMSK
ldr r1,=0xffffffff ;all interrupt disable
str r1,[r0]

ldr r0,=INTSUBMSK
ldr r1,=0x7ff ;all sub interrupt disable, 2002/04/10
str r1,[r0]

[ {FALSE}
; rGPFDAT = (rGPFDAT & ~(0xf<<4)) | ((~data & 0xf)<<4);
; Led_Display
ldr r0,=GPFCON
ldr r1,=0x5500
str r1,[r0]
ldr r0,=GPFDAT
ldr r1,=0x10
str r1,[r0]
]
;2.根据工作频率设置pll
;这里介绍一下计算公式
;Fpllo=(m*Fin)/(p*2^s)
;m=MDIV+8,p=PDIV+2,s=SDIV
;Fpllo必须大于20Mhz小于66Mhz
;Fpllo*2^s必须小于170Mhz
;如下面的PLLCON设定中的M_DIV P_DIV S_DIV是取自option.h中
;#elif (MCLK==40000000)
;#define PLL_M (0x48)
;#define PLL_P (0x3)
;#define PLL_S (0x2)
;所以m=MDIV+8=80,p=PDIV+2=5,s=SDIV=2
;硬件使用晶振为10Mhz,即Fin=10Mhz
;Fpllo=80*10/5*2^2=40Mhz
;To reduce PLL lock time, adjust the LOCKTIME register.
ldr r0,=LOCKTIME
ldr r1,=0xffffff
str r1,[r0]

[ PLL_ON_START
;Configure MPLL
ldr r0,=MPLLCON
ldr r1,=((M_MDIV<<12)+(M_PDIV<<4)+M_SDIV) ;Fin=12MHz,Fout=50MHz
str r1,[r0]
]

;Check if the boot is caused by the wake-up from POWER_OFF mode.
ldr r1,=GSTATUS2
ldr r0,[r1]
tst r0,#0x2
;In case of the wake-up from POWER_OFF mode, go to POWER_OFF_WAKEUP handler.
bne WAKEUP_POWER_OFF

EXPORT StartPointAfterPowerOffWakeUp
StartPointAfterPowerOffWakeUp
;3.置存储相关寄存器的程序
;这是设置SDRAM,flash ROM 存储器连接和工作时序的程序,片选定义的程序
;SMRDATA map在下面的程序中定义
;SMRDATA中涉及的值请参考memcfg.s程序
;具体寄存器各位含义请参考s3c44b0 spec
;Set memory control registers
ldr r0,=SMRDATA
ldr r1,=BWSCON ;BWSCON Address
add r2, r0, #52 ;End address of SMRDATA
0
ldr r3, [r0], #4
str r3, [r1], #4
cmp r2, r0
bne %B0

;Initialize stacks
bl InitStacks
;5.设置缺省中断处理函数
; Setup IRQ handler
ldr r0,=HandleIRQ ;This routine is needed
ldr r1,=IsrIRQ ;if there isnt subs pc,lr,#4 at 0x18, 0x1c
str r1,[r0]

;Copy and paste RW data/zero initialized data
ldr r0, =|Image$$RO$$Limit| ; Get pointer to ROM data
ldr r1, =|Image$$RW$$Base| ; and RAM copy
ldr r3, =|Image$$ZI$$Base|
;6.将数据段拷贝到ram中将零初始化数据段清零跳入C语言的main函数执行到这步结束bootloader初步引导结束
;Zero init base => top of initialised data
cmp r0, r1 ; Check that they are different
beq %F2
1
cmp r1, r3 ; Copy init data
ldrcc r2, [r0], #4 ;--> LDRCC r2, [r0] + ADD r0, r0, #4
strcc r2, [r1], #4 ;--> STRCC r2, [r1] + ADD r1, r1, #4
bcc %B1 ;r1 < r3 继续循环
2
ldr r1, =|Image$$ZI$$Limit| ; Top of zero init segment
mov r2, #0
3
cmp r3, r1 ; Zero init
strcc r2, [r3], #4
bcc %B3

[ : lNOT:THUMBCODE
bl Main ; Dont use main() because ......
b .
]

[ THUMBCODE ;for start-up code for Thumb mode
orr lr,pc,#1
bx lr
CODE16
bl Main ; Dont use main() because ......
b .
CODE32
]

;function initializing stacks
InitStacks
; Dont use DRAM,such as stmfd,ldmfd......
;SVCstack is initialized before
;Under toolkit ver 2.5, msr cpsr,r1 can be used instead of msr cpsr_cxsf,r1
mrs r0,cpsr
bic r0,r0,#MODEMASK ;位清零指令,清r0,再附给ro
orr r1,r0,#UNDEFMODE|NOINT
msr cpsr_cxsf,r1 ;UndefMode
ldr sp,=UndefStack

orr r1,r0,#ABORTMODE|NOINT
msr cpsr_cxsf,r1 ;AbortMode
ldr sp,=AbortStack

orr r1,r0,#IRQMODE|NOINT
msr cpsr_cxsf,r1 ;IRQMode
ldr sp,=IRQStack

orr r1,r0,#FIQMODE|NOINT
msr cpsr_cxsf,r1 ;FIQMode
ldr sp,=FIQStack

bic r0,r0,#MODEMASK|NOINT
orr r1,r0,#SVCMODE
msr cpsr_cxsf,r1 ;SVCMode
ldr sp,=SVCStack

;USER mode has not be initialized.

mov pc,lr
;The LR register wont be valid if the current mode is not SVC mode.

;这是上面提到的对存储寄存器初始化的数据map
LTORG

SMRDATA DATA
; Memory configuration should be optimized for best performance
; The following parameter is not optimized.
; Memory access cycle parameter strategy
; 1) The memory settings is safe parameters even at HCLK=75Mhz.
; 2) SDRAM refresh period is for HCLK=75Mhz.

DCD (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))
DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC)) ;GCS0
DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC)) ;GCS1
DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC)) ;GCS2
DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC)) ;GCS3
DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC)) ;GCS4
DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC)) ;GCS5
DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN)) ;GCS6
DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN)) ;GCS7
; DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT) ;Tchr not used bit
DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+REFCNT) ;设置刷新周期

; DCD 0x32 ;SCLK power saving mode, ARM core burst disable, BANKSIZE 128M/128M
DCD 0xb2 ;SCLK power saving mode, ARM core burst enable , BANKSIZE 128M/128M - 11/29/2002

DCD 0x30 ;MRSR6 CL=3clk
DCD 0x30 ;MRSR7
; DCD 0x20 ;MRSR6 CL=2clk
; DCD 0x20 ;MRSR7

ALIGN

AREA RamData, DATA, READWRITE
;这里将中断异常向量建立在sdram中
^ _ISR_STARTADDRESS
HandleReset # 4
HandleUndef # 4
HandleSWI # 4
HandlePabort # 4
HandleDabort # 4
HandleReserved # 4
HandleIRQ # 4
HandleFIQ # 4

; Dont use the label IntVectorTable,
;The value of IntVectorTable is different with the address you think it may be.
;IntVectorTable
HandleEINT0 # 4
HandleEINT1 # 4
HandleEINT2 # 4
HandleEINT3 # 4
HandleEINT4_7 # 4
HandleEINT8_23 # 4
HandleRSV6 # 4
HandleBATFLT # 4
HandleTICK # 4
HandleWDT # 4
HandleTIMER0 # 4
HandleTIMER1 # 4
HandleTIMER2 # 4
HandleTIMER3 # 4
HandleTIMER4 # 4
HandleUART2 # 4
HandleLCD # 4
HandleDMA0 # 4
HandleDMA1 # 4
HandleDMA2 # 4
HandleDMA3 # 4
HandleMMC # 4
HandleSPI0 # 4
HandleUART1 # 4
HandleRSV24 # 4
HandleUSBD # 4
HandleUSBH # 4
HandleIIC # 4
HandleUART0 # 4
HandleSPI1 # 4
HandleRTC # 4
HandleADC # 4

END

最后发两个在网上下载的ARM S3C44B0的注释文件，是转载别人的。希望对各位有用。

2006/7/22
44B0XINIT注释
*******************************************************
; * NAME : 44BINIT.S *
; * Version : 10.JAn.2003 *
; * Description: *
; * C start up codes *
; * Configure memory, Initialize ISR ,stacks *
; * Initialize C-variables *
; * Fill zeros into zero-initialized C-variables *
; *******************************************************
GET option.s ;相当于c语言中的#include option.s
GET memcfg.s
;Interrupt Control /P154
;声明一些符号常量，这些符号常量和地址相应寄存器的地址对应
INTPND EQU 0x01e00004 ;指示中断请求状态寄存器每一位代变一种中断请求具体表示哪一种中断请参考44b0 spec
INTMOD EQU 0x01e00008 ;中断模式寄存器有两种中断模式对应位为1代表fip mode 0代表riq mode
INTMSK EQU 0x01e0000c ;确定哪个中断源被屏蔽屏蔽的中断源将不被服务
I_ISPR EQU 0x01e00020 ;中断服务挂起寄存器
I_CMST EQU 0x01e0001c ;当前主寄存器irq优先级
;Watchdog timer
WTCON EQU 0x01d30000 ;看门狗定时器控制寄存器
;Clock Controller
PLLCON EQU 0x01d80000 ; pll控制寄存器
CLKCON EQU 0x01d80004 ;时钟控制寄存器
LOCKTIME EQU 0x01d8000c ;锁定时间计数值寄存器
;Memory Controller
REFRESH EQU 0x01c80024 ; Dram/sdram刷新控制寄存器
;下面是对arm处理器模式寄存器对应值的常数定义，arm处理器中有一个CPSR程序状态寄存器它的后五位决定目前的处理器模式
; pre-defined constants
USERMODE EQU 0x10 ;0b10000用户模式
FIQMODE EQU 0x11 ;0b10001FIQ模式
IRQMODE EQU 0x12 ;0b10010IRQ模式
SVCMODE EQU 0x13 ;0b10011管理模式
ABORTMODE EQU 0x17 ;0b10111中止模式
UNDEFMODE EQU 0x1b ;0b11011未定义
MODEMASK EQU 0x1f ;0b11111系统模式
NOINT EQU 0xc0 ;
;check if tasm.exe is used.
;arm处理器有两种工作状态 1.arm:32位这种工作状态下执行字对准的arm指令 2.Thumb:16位这种工作状;态执行半字对准的Thumb指令
;因为处理器分为16位 32位两种工作状态程序的编译器也是分16位和32两种编译方式所以下面的程序用;于根据处理器工作状态确定编译器编译方式
;code16伪指令指示汇编编译器后面的指令为16位的thumb指令
;code32伪指令指示汇编编译器后面的指令为32位的arm指令
;这段是为了统一目前的处理器工作状态和软件编译方式（16位编译环境使用tasm.exe编译）
GBLL THUMBCODE ;设置一个全局逻辑变量
[ {CONFIG} = 16 ;if config==16 这里表示你的目前处于领先地16位编译方式
THUMBCODE SETL {TRUE} ;设置THUMBCODE 为 true
CODE32 ;转入32位编译模式
| 次 ;else
THUMBCODE SETL {FALSE} ;设置THUMBCODE 为 false
]
[ THUMBCODE ;if THUMBCODE==TRUE
CODE32 ;for start-up code for Thumb mode;转入32位编译方式
]
;注意下面这段程序是个宏定义很多人对这段程序不理解我再次强调这是一个宏定义所以大家要注意了;下面包含的HandlerXXX HANDLER HandleXXX将都被下面这段程序展开
;这段程序用于把中断服务程序的首地址装载到pc中，有人称之为“加载程序”。
;本初始化程序定义了一个数据区（在文件最后），34个字空间，存放相应中断服务程序的首地址。每个字;空间都有一个标号，以Handle***命名。
;在向量中断模式下使用“加载程序”来执行中断服务程序。
;这里就必须讲一下向量中断模式和非向量中断模式的概念
;向量中断模式是当cpu读取位于0x18处的IRQ中断指令的时候，系统自动读取对应于该中断源确定地址上的;指令取代0x18处的指令，通过跳转指令系统就直接跳转到对应地址
;函数中节省了中断处理时间提高了中断处理速度标例如 ADC中断的向量地址为0xC0,则在0xC0处放如下;代码：ldr PC,=HandlerADC 当ADC中断产生的时候系统会
;自动跳转到HandlerADC函数中
;非向量中断模式处理方式是一种传统的中断处理方法，当系统产生中断的时候，系统将interrupt ; pending寄存器中对应标志位置位然后跳转到位于0x18处的统一中断
;函数中该函数通过读取interrupt pending寄存器中对应标志位来判断中断源并根据优先级关系再跳到;对应中断源的处理代码中
MACRO
$HandlerLabel HANDLER $HandleLabel
$HandlerLabel
sub sp,sp,#4 ; Decrement sp(to store jump address)
stmfd sp!,{r0} ; pUSH the work register to stack
;将要使用的r0寄存器入栈
ldr r0,=$HandleLabel; load the address of HandleXXX to r0
ldr r0,[r0] ; load the contents(service routine start address) of HandleXXX
str r0,[sp,#4] ;store the contents(ISR) of HandleXXX to stack
;将对应的中断函数首地址入栈
ldmfd sp!,{r0,pc} ; pOP the work register and pc(jump to ISR)
;将中断函数首地址出栈放入程序指针中系统将跳转到对应中断处理函数
MEND
;一个arm由RO,RW,ZI三个断组成其中RO为代码段，RW是已经初始化的全局变量，ZI是未初始化的全局变量;（对于GNU工具对应的概念是TEXT ,DATA,BSS）bootloader
;bootloader要将RW段复制到ram中并将ZI段清零编译器使用下列段来记录各段的起始和结束地址
; |Image$$RO$$Base| ; RO段起始地址
; |Image$$RO$$Limit| ; RO段结束地址加1
; |Image$$RW$$Base| ; RW段起始地址
; |Image$$RW$$Limit| ; RW段结束地址加1
; |Image$$ZI$$Base| ; ZI段起始地址
; |Image$$ZI$$Limit| ; ZI段结束地址加1
;这些标号的值是通过编译器的设定来确定的如编译软件中对ro-base和rw-base的设定，例如 ro-;base=0xc000000 rw-base=0xc5f0000

IMPORT |Image$$RO$$Limit| ; End of ROM code (=start of ROM data)
IMPORT |Image$$RW$$Base| ; Base of RAM to initialise
IMPORT |Image$$ZI$$Base| ; Base and limit of area
IMPORT |Image$$ZI$$Limit| ; to zero initialise
IMPORT Main ; The main entry of mon program
;下面为代码段
AREA Init,CODE,READONLY
;异常中断矢量表（每个表项占4个字节）下面是中断向量表一旦系统运行时有中断发生即使移植了操作;系统如linux 处理器已经把控制权;交给了操作系统一旦发生中断处理器还是会跳转到从0x0开始
;中断向量表中某个中断表项（依据中断类型）开始执行
;具体中断向量布局请参考s3c44b0 spec 例如 adc中断向量为 0x000000c0下面对应表中第49项位置向量地址0x0+4*(49-1)=0x000000c0
ENTRY
;板子上电和复位后程序开始从位于0x0处开始执行硬件刚刚上电复位后程序从这里开始执行跳转到标号为ResetHandler处执行
b ResetHandler ;for debug
b HandlerUndef ;handlerUndef
b HandlerSWI ;SWI interrupt handler
b HandlerPabort ;handlerPAbort
b HandlerDabort ;handlerDAbort
b . ;handlerReserved
b HandlerIRQ
b HandlerFIQ
;***IMPORTANT NOTE***
;If the H/W vectored interrutp mode is enabled, The above two instructions should
;be changed like below, to work-around with H/W bug of S3C44B0X interrupt controller.
; b HandlerIRQ -> subs pc,lr,#4
; b HandlerIRQ -> subs pc,lr,#4
VECTOR_BRANCH
ldr pc,=HandlerEINT0 ;mGA H/W interrupt vector table
ldr pc,=HandlerEINT1 ;
ldr pc,=HandlerEINT2 ;
ldr pc,=HandlerEINT3 ;
ldr pc,=HandlerEINT4567 ;
ldr pc,=HandlerTICK ;mGA
b .
b .
ldr pc,=HandlerZDMA0 ;mGB
ldr pc,=HandlerZDMA1 ;
ldr pc,=HandlerBDMA0 ;
ldr pc,=HandlerBDMA1 ;
ldr pc,=HandlerWDT ;
ldr pc,=HandlerUERR01 ;mGB
b .
b .
ldr pc,=HandlerTIMER0 ;mGC
ldr pc,=HandlerTIMER1 ;
ldr pc,=HandlerTIMER2 ;
ldr pc,=HandlerTIMER3 ;
ldr pc,=HandlerTIMER4 ;
ldr pc,=HandlerTIMER5 ;mGC
b .
b .
ldr pc,=HandlerURXD0 ;mGD
ldr pc,=HandlerURXD1 ;
ldr pc,=HandlerIIC ;
ldr pc,=HandlerSIO ;
ldr pc,=HandlerUTXD0 ;
ldr pc,=HandlerUTXD1 ;mGD
b .
b .
ldr pc,=HandlerRTC ;mGKA
b . ;
b . ;
b . ;
b . ;
b . ;mGKA
b .
b .
ldr pc,=HandlerADC ;mGKB
b . ;
b . ;
b . ;
b . ;
b . ;mGKB
b .
b .
;0xe0=EnterPWDN
ldr pc,=EnterPWDN
LTORG
;下面是具体的中断处理函数跳转的宏，通过上面的$HandlerLabel的宏定义展开后跳转到对应的中断处理;函数（对于向量中断）
HandlerFIQ HANDLER HandleFIQ
HandlerIRQ HANDLER HandleIRQ
HandlerUndef HANDLER HandleUndef
HandlerSWI HANDLER HandleSWI
HandlerDabort HANDLER HandleDabort
HandlerPabort HANDLER HandlePabort
HandlerADC HANDLER HandleADC
HandlerRTC HANDLER HandleRTC
HandlerUTXD1 HANDLER HandleUTXD1
HandlerUTXD0 HANDLER HandleUTXD0
HandlerSIO HANDLER HandleSIO
HandlerIIC HANDLER HandleIIC
HandlerURXD1 HANDLER HandleURXD1
HandlerURXD0 HANDLER HandleURXD0
HandlerTIMER5 HANDLER HandleTIMER5
HandlerTIMER4 HANDLER HandleTIMER4
HandlerTIMER3 HANDLER HandleTIMER3
HandlerTIMER2 HANDLER HandleTIMER2
HandlerTIMER1 HANDLER HandleTIMER1
HandlerTIMER0 HANDLER HandleTIMER0
HandlerUERR01 HANDLER HandleUERR01
HandlerWDT HANDLER HandleWDT
HandlerBDMA1 HANDLER HandleBDMA1
HandlerBDMA0 HANDLER HandleBDMA0
HandlerZDMA1 HANDLER HandleZDMA1
HandlerZDMA0 HANDLER HandleZDMA0
HandlerTICK HANDLER HandleTICK
HandlerEINT4567 HANDLER HandleEINT4567
HandlerEINT3 HANDLER HandleEINT3
HandlerEINT2 HANDLER HandleEINT2
HandlerEINT1 HANDLER HandleEINT1
HandlerEINT0 HANDLER HandleEINT0

;One of the following two routines can be used for non-vectored interrupt.
;下面这段程序是用来处理非向量中断，具体判断I_ISPR中各位是否置1 置1表示目前此中断等待响应（每次只能有一位置1），从最高优先级中断位开始判断，检测到等待服务
;中断就将pc置为中断服务函数首地址
IsrIRQ ;using I_ISPR register.
sub sp,sp,#4 ;reserved for PC
stmfd sp!,{r8-r9}
;IMPORTANT CAUTION
;if I_ISPC isnt used properly, I_ISPR can be 0 in this routine.
ldr r9,=I_ISPR
ldr r9,[r9]
mov r8,#0x0
0
movs r9,r9,lsr #1
bcs %F1
add r8,r8,#4
b %B0
1
ldr r9,=HandleADC
add r9,r9,r8
ldr r9,[r9]
str r9,[sp,#8]
ldmfd sp!,{r8-r9,pc}

;****************************************************
;* START *
;****************************************************
;扳子上电和复位后程序开始从位于0x0执行b ResetHandler 程序从跳转到这里执行
;板子上电复位后执行几个步骤这里通过标号在注释中加1，2，3....标示标号表示执行顺序
;1.禁止看门狗屏蔽所有中断
ResetHandler
ldr r0,=WTCON ;watch dog disable
ldr r1,=0x0
str r1,[r0]
ldr r0,=INTMSK
ldr r1,=0x07ffffff ;all interrupt disable
str r1,[r0]
;2.根据工作频率设置pll
;这里介绍一下计算公式
;Fpllo=(m*Fin)/(p*2^s)
;m=MDIV+8,p=PDIV+2,s=SDIV
;Fpllo必须大于20Mhz小于66Mhz
;Fpllo*2^s必须小于170Mhz
;如下面的PLLCON设定中的M_DIV P_DIV S_DIV是取自option.h中
;#elif (MCLK==40000000)
;#define PLL_M (0x48)
;#define PLL_P (0x3)
;#define PLL_S (0x2)
;所以m=MDIV+8=80,p=PDIV+2=5,s=SDIV=2
;硬件使用晶振为10Mhz,即Fin=10Mhz
;Fpllo=80*10/5*2^2=40Mhz
;****************************************************
;* Set clock control registers *
;****************************************************
ldr r0,=LOCKTIME
ldr r1,=800 ; count = t_lock * Fin (t_lock=200us, Fin=4MHz) = 800
str r1,[r0]
[ PLLONSTART
ldr r0,=PLLCON ;temporary setting of PLL
ldr r1,=((M_DIV<<12)+(P_DIV<<4)+S_DIV) ;Fin=10MHz,Fout=40MHz
str r1,[r0]
]
ldr r0,=CLKCON
ldr r1,=0x7ff8 ;All unit block CLK enable
str r1,[r0]
;3.置存储相关寄存器的程序
;这是设置SDRAM,flash ROM 存储器连接和工作时序的程序,片选定义的程序
;SMRDATA map在下面的程序中定义
;SMRDATA中涉及的值请参考memcfg.s程序
;具体寄存器各位含义请参考s3c44b0 spec
;****************************************************
;* Set memory control registers *
;****************************************************
ldr r0,=SMRDATA
ldmia r0,{r1-r13}
ldr r0,=0x01c80000 ;BWSCON Address
stmia r0,{r1-r13}
;****************************************************
;* Initialize stacks *
;****************************************************
ldr sp, =SVCStack ;Why?
bl InitStacks
;5.设置缺省中断处理函数
;****************************************************
;* Setup IRQ handler *
;****************************************************
ldr r0,=HandleIRQ ;This routine is needed
ldr r1,=IsrIRQ ;if there isnt subs pc,lr,#4 at 0x18, 0x1c
str r1,[r0]
;6.将数据段拷贝到ram中将零初始化数据段清零跳入C语言的main函数执行到这步结束bootloader初步引导结束
;********************************************************
;* Copy and paste RW data/zero initialized data *
;********************************************************
LDR r0, =|Image$$RO$$Limit| ; Get pointer to ROM data
LDR r1, =|Image$$RW$$Base| ; and RAM copy
LDR r3, =|Image$$ZI$$Base|
;Zero init base => top of initialised data
CMP r0, r1 ; Check that they are different
BEQ %F1
0
CMP r1, r3 ; Copy init data
LDRCC r2, [r0], #4 ;--> LDRCC r2, [r0] + ADD r0, r0, #4
STRCC r2, [r1], #4 ;--> STRCC r2, [r1] + ADD r1, r1, #4
BCC %B0
1
LDR r1, =|Image$$ZI$$Limit| ; Top of zero init segment
MOV r2, #0
2
CMP r3, r1 ; Zero init
STRCC r2, [r3], #4
BCC %B2
[ : lNOT:THUMBCODE
BL Main ; Dont use main() because ......;跳入main函数
B .
]
[ THUMBCODE ;for start-up code for Thumb mode
orr lr,pc,#1
bx lr
CODE16
bl Main ; Dont use main() because ......;跳入main函数
b .
CODE32
]
;4.初始化各模式下的栈指针
;****************************************************
;* The function for initializing stack *
;****************************************************
InitStacks
; Dont use DRAM,such as stmfd,ldmfd......
;SVCstack is initialized before
;Under toolkit ver 2.50, msr cpsr,r1 can be used instead of msr cpsr_cxsf,r1
mrs r0,cpsr
bic r0,r0,#MODEMASK
orr r1,r0,#UNDEFMODE|NOINT
msr cpsr_cxsf,r1 ;UndefMode
ldr sp,=UndefStack
orr r1,r0,#ABORTMODE|NOINT
msr cpsr_cxsf,r1 ;AbortMode
ldr sp,=AbortStack
orr r1,r0,#IRQMODE|NOINT
msr cpsr_cxsf,r1 ;IRQMode
ldr sp,=IRQStack
orr r1,r0,#FIQMODE|NOINT
msr cpsr_cxsf,r1 ;FIQMode
ldr sp,=FIQStack
bic r0,r0,#MODEMASK|NOINT
orr r1,r0,#SVCMODE
msr cpsr_cxsf,r1 ;SVCMode
ldr sp,=SVCStack
;USER mode is not initialized.
mov pc,lr ;The LR register may be not valid for the mode changes.
;下面是pwdn模式下的相关寄存器的定义
;****************************************************
;* The function for entering power down mode *
;****************************************************
;void EnterPWDN(int CLKCON);
EnterPWDN
mov r2,r0 ;r0=CLKCON
ldr r0,=REFRESH
ldr r3,[r0]
mov r1, r3
orr r1, r1, #0x400000 ;self-refresh enable
str r1, [r0]
nop ;Wait until self-refresh is issued. May not be needed.
nop ;If the other bus master holds the bus, ...
nop ; mov r0, r0
nop
nop
nop
nop
;enter POWERDN mode
ldr r0,=CLKCON
str r2,[r0]
;wait until enter SL_IDLE,STOP mode and until wake-up
mov r0,#0xff
0 subs r0,r0,#1
bne %B0
;exit from DRAM/SDRAM self refresh mode.
ldr r0,=REFRESH
str r3,[r0]
mov pc,lr
LTORG
;这是上面提到的对存储寄存器初始化的数据map
SMRDATA DATA
;*****************************************************************
;* Memory configuration has to be optimized for best performance *
;* The following parameter is not optimized. *
;*****************************************************************
;*** memory access cycle parameter strategy ***
; 1) Even FP-DRAM, EDO setting has more late fetch point by half-clock
; 2) The memory settings,here, are made the safe parameters even at 66Mhz.
; 3) FP-DRAM Parameters:tRCD=3 for tRAC, tcas=2 for pad delay, tcp=2 for bus load.
; 4) DRAM refresh rate is for 40Mhz.

DCD 0x11110090 ;Bank0=OM[1:0], Bank1~Bank7=16bit, bank2=8bit;
DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC)) ;GCS0
DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC)) ;GCS1
DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC)) ;GCS2
DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC)) ;GCS3
DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC)) ;GCS4
DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC)) ;GCS5
DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN)) ;GCS6
DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN)) ;GCS7
DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT) ;REFRESH RFEN=1, TREFMD=0, trp=3clk, trc=5clk, tchr=3clk,count=1019
DCD 0x16 ;SCLK power mode, BANKSIZE 32M/32M
DCD 0x20 ;MRSR6 CL=2clk
DCD 0x20 ;MRSR7
ALIGN
;下面是对ram区域map的定义
AREA RamData, DATA, READWRITE
;这里定义了处理器工作于各模式的堆栈区在ram中map
^ (_ISR_STARTADDRESS-0x500)
UserStack # 256 ;c1(c7)ffa00
SVCStack # 256 ;c1(c7)ffb00
UndefStack # 256 ;c1(c7)ffc00
AbortStack # 256 ;c1(c7)ffd00
IRQStack # 256 ;c1(c7)ffe00
FIQStack # 0 ;c1(c7)fff00
;这里将中断异常向量建立在sdram中
^ _ISR_STARTADDRESS
HandleReset # 4
HandleUndef # 4
HandleSWI # 4
HandlePabort # 4
HandleDabort # 4
HandleReserved # 4
HandleIRQ # 4
HandleFIQ # 4
; Dont use the label IntVectorTable,
;because armasm.exe cannt recognize this label correctly.
;the value is different with an address you think it may be.
;IntVectorTable
HandleADC # 4
HandleRTC # 4
HandleUTXD1 # 4
HandleUTXD0 # 4
HandleSIO # 4
HandleIIC # 4
HandleURXD1 # 4
HandleURXD0 # 4
HandleTIMER5 # 4
HandleTIMER4 # 4
HandleTIMER3 # 4
HandleTIMER2 # 4
HandleTIMER1 # 4
HandleTIMER0 # 4
HandleUERR01 # 4
HandleWDT # 4
HandleBDMA1 # 4
HandleBDMA0 # 4
HandleZDMA1 # 4
HandleZDMA0 # 4
HandleTICK # 4
HandleEINT4567 # 4
HandleEINT3 # 4
HandleEINT2 # 4
HandleEINT1 # 4
HandleEINT0 # 4 ;0xc1(c7)fff84
END

这是另外一个人写的体会：

ARM(44b0)初学者总结（转载）
我的开发板是s3c44b0x的， 2m NOR FLASH在bank0,8m sdram在bank6.首先看看我们要解决的问题。有些ARM芯片有内嵌的RAM 和FALSH.这样可以直接在片内运行程序，44B0X片内只有几K CACHE，ROM和RAM都是外接的芯片。我们的程序是要写入FLASH中保存，但执行时是拷到SDRAM中执行的（如在ROM中执行速度会较慢）。要做到这一点需要把程序做成两个分程序：一个是实现你的系统功能的主程序，如果你用嵌入式系统，那就是UCOS和UCLINUX之类的程序，这个程序的代码保存在FLASH中，但执行时会拷到RAM中再执行；一个是引导程序，直接在FLASH中执行，负责把初始化芯片和外设，并把主程序从FLASH中拷到 RAM中，然后跳到主程序去执行，对应的概念是UBOOT等常见的引导程序，这个程序会被写入0X0开始的地址，开机后自动执行。
那么我们需要解决以下几个问题：
1.如何编译和调试主程序
2.如何使中断跳到RAM中的中断服务程序执行
3.如何把引导程序和主程序写入FLASH中.
以下我们来解决这几个问题：
1 开始在仿真器中写代码和调试
由于主程序会被拷贝到RAM中执行，则我们应该在编译时就把程序定位到RAM中。这里先要说说几个ADS的参数的意义,在ADS的ARM LINKER页有RO,RW两个参数，此外还有一个ZI没有在页中给出，RO是只读代码的起始地址，由这个地址开始存放编译出来的程序指令；RW是程序的读写段的开始，即你程序中的数据存放的开始地址，ZI紧跟在RW区后，ZI区存放的是需要在程序运行时初始化为0的数据。
了解这几个链接参数的意义后我们可以设置这几个参数了：对于我的44B0X板8M SDRAM在0XC00_0000.因此在开发时把ADS中的RO BASE的地址指定为0XC00_0000;置于RW,在程序完成前可以预先估计一下程序的体积有多大，需要用到的数据区有多大，避免数据区太小或代码区覆盖掉前面的数据区就是了，我用了0XC10_0000,1M的代码空间，其他作数据区。这样，我们编译出来的程序代码就是在0XC00_0000中，可以直接由仿真器写入RAM中运行仿真运行。此外，在linker-〉layout页有个object symbol和section的选项，要求你填入映像文件最开始的object文件名和段名，这两个参数在仿真时不填写也不会影响运行，因为仿真器会自动修改pc指针，但要建立能烧写的映像文件，则一定要填写好，具体填写什么后面分析程序时再讲。
2中断问题
和所有单片机一样，ARM复位后从地址0X0开始执行，而0X0后是一串默认的中断向量表。对51这样的芯片，我们会直接在这个中断向量表中填入跳转语句，让它跳到指定的ISR处理中断事件。由于我们的主程序是在RAM中执行的，编译时又和引导程序分开，不可能预先知道我们写的ISR具体地址，而预留的中断向量表只够每个中断一个跳转指令，因此我们需要做二次跳转。在内存中建立一个中断向量表，每个中断对应一个字，存放ISR的地址。尔后，对每个中断写一段短的代码，把ISR地址取出，填入PC。而0X0后面中断向量的跳转指令，则是跳到这小段程序中。
3烧写flash,ADX中似乎有个写入flash的选项，我自己没有具体用过。但听说用jtag写flash会比较慢。由于nor flash或nand flash都是可以编程烧写的，即我们可以写个程序擦写flash,问题是如何读取编译出来的映像文件。这个也不用担心，adx中有个菜单把文件内容写入指定的地址中，把影响文件指定到一个ram地址，然后就用烧写程序把ram的内容拷入rom中就是了。我们有个boot程序，一个主程序要映射到rom 中.假设我把0xc20_0000开始的2m地址作rom的映像，则把boot程序导入0xc20_0000,boot的程序非常短，在 0xc20_1000开始放主程序。然后把0xc20_0000到0xc40_0000的内容全部拷入rom中（当然在导入文件前这些ram应该先被清空或写入ff.）。
让我们来看看相关的代码，具体认识一下该怎么处理前面说的这些问题，还有另外的一些问题。这里使用的代码是在44b0x的application note的第三章中拿出来的，这个文件在网上应该很容易找到。
程序的入口在44binit.s汇编文件中，其中一个Init 段是整个程序的入口：
AREA Init,CODE,READONLY
ENTRY
b ResetHandler ;for debug
b HandlerUndef ;handlerUndef
b HandlerSWI ;SWI interrupt handler
b HandlerPabort ;handlerPAbort
b HandlerDabort ;handlerDAbort
b . ;handlerReserved
b HandlerIRQ
关键字ENTRY告诉编译器保留这段代码。从代码看INIT段就是要写入0X0地址的原始中断向量，因此把这个文件编译生成的44BINIT.O和 INTT填入上面提到的LAYOUT页对应项中。这样编译器会把该段代码编译到0X0地址。（仿真时你可以试试别填这两个项目，看看ADX中的反汇编代码入口被放到哪里）。
这段代码里除了reset句外，有每句都有一个HandlerXXX的标号，这就是前面提到的中断处理程序的入口，它是由前面的一个宏来定义的：
MACRO
$HandlerLabel HANDLER $HandleLabel
$HandlerLabel
sub sp,sp,#4 ; Decrement sp(to store jump address)
stmfd sp!,{r0}
; pUSH the work register to stack(lr doest push because it return to original address)
ldr r0,=$HandleLabel; load the address of HandleXXX to r0
ldr r0,[r0] ; load the contents(service routine start address) of HandleXXX
str r0,[sp,#4] ;store the contents(ISR) of HandleXXX to stack
ldmfd sp!,{r0,pc} ; pOP the work register and pc(jump to ISR)
MEND
我自己没有写过宏，所以还是看编译出来的代码比较直接：
HandlerSWI
0x0c000198: e24dd004 ..M. SUB r13,r13,#4
0x0c00019c: e92d0001 ..-. STMFD r13!,{r0}
0x0c0001a0: e59f0458 X... LDR r0,0xc000600
0x0c0001a4: e5900000 .... LDR r0,[r0,#0]
0x0c0001a8: e58d0004 .... STR r0,[r13,#4]
0x0c0001ac: e8bd8001 .... LDMFD r13!,{r0,pc}
这是ads输出的汇编代码，就是刚才的宏对应swi的一个实例，其中有两句
LDR r0,0xc000600
LDR r0,[r0,#0]
是把0x0c000600的内容载入r0,再把r0地址的ram单元载入r0.去看看0xc000600的内容，是0X0c7fff08，这是我设定的内存中的中断向量表地址之一，中断向量表的起始地址是0X0c7fff00，因此0X0c7fff08存放的刚好就是swi的isr地址。后面程序就跳到对应的ISR去了。（这段宏程序由于我不熟悉arm的汇编，只看过它怎么执行，实在我不知道中断向量表地址是如何被放入0x0c000600等地址的。希望有高手能再详细解释一下具体的编写，编译方法和原理。）
在c程序中，我们需要给每个中断向量定义一个宏：
#define pISR_SWI (*(unsigned *)(_ISR_STARTADDRESS+0x08))
_ISR_STARTADDRESS是起始地址0X0c7fff00,假设ISR是以下函数：
void __irq SWI_UserIsr(void){……………}
则在系统初始化时用pISR_EINT0=(unsigned)SWI_UserIsr;这样的语句把ISR的地址填入中断向量表中,对所有中断作同样的处理，然后开中断，系统就能经过上面的宏把跳到ISR执行。
44binit.s中还有几段值得留意的代码：以下的代码把rw段的数据拷入ram中，并初始化zi段，即把该段清零：
LDR r0,=|Image$$RO$$Limit|
LDR r1,=|Image$$RW$$Base|
LDR r2,=|Image$$ZI$$Base|
CMP r0,r1
BEQ %F1
0 CMP r1,r3
LDRCC r2,[r0],#4
STRCC r2,[r1],#4
BCC %B0
1 LDR r1,=|Image$$ZI$$Limit|
MOV r2,#0
2 CMP r3,r1
&n, bsp; STRCC r2,[r3],#4
BCC %B2
来看反汇编的代码：
0x0c000ae0: e59f0194 .... LDR r0,0xc000c7c
0x0c000ae4: e59f1194 .... LDR r1,0xc000c80
0x0c000ae8: e59f3194 .1.. LDR r3,0xc000c84
0xc000c7c,开始的三个字的内容是：
0x0c000c7c: 0c000e10 .... DCD 201330192
0x0c000c80: 0c200000 .. . DCD 203423744
0x0c000c84: 0c200000 .. . DCD 203423744
0x0c000c88: 0c200004 .. . DCD 203423748
这些反汇编的代码是一个点led的程序的，可以看出我的小程序代码到0x0c000e10就结束了，0x0c200000是我指定的数据区起始地址。这段程序把|Image$$RO$$Limit| 开始的,长|Image$$ZI$$Base| -|Image$$RW$$Base| 的数据区拷到|Image$$RW$$Base|的对应单元，就是0x0c200000开始的一段ram中。后面还有|Image$$ZI$$ Limit|，在我的代码中是0x0c000c88，内容是0x0c200004.这其实表明我的小程序并没有rw区，只有一个初始为0的变量。
另外还有一段初始化ram控制器的代码：
;****************************************************
;* Set memory control registers
;****************************************************
ldr r0,=SMRDATA
ldmia r0,{r1-r13}
ldr r0,=0x01c80000 ;BWSCON Address
stmia r0,{r1-r13}，
由于44b0x要求13个控制寄存器要一次完成填入，所以先把参数设定在SMRDATA的地址中，一次载入通用寄存器，在一次填入RAM控制寄存器中。 4510的书上介绍调试前需要用SEMEM命令设置这些寄存器，但我自己没有那么做也可以跑的很好，也许是默认已经用了最保守的配置的原因吧！
其余的代码解释比较清晰了，最后摘出我的LED程序和这个小程序的BOOT程序以及烧写程序。这几个程序的project都包括了 44binit.s, option.s, memcfg.s，option.h,44b.h几个从app note中抄来的文件，这里只列了我自己写的主要c代码。其他这些文件我除了把ram和rom的对应配置改了一下外，都没有改动。我的引导程序编译出来是 3k,led程序也是3k,因此我把他们分别定位在rom的0x0和0x2000处，一共写了8k。
LED程序中的44BINTT.S程序功能和LOAD中的44BINTT.S是重复的，主要是我懒得去修改这些汇编，由着他们占用一点时间吧！
load程序负责把从0x20000处开始的4k程序（即led程序）拷到ram 0xc000000中，run函数把pc指到0x0c000000,开始执行led程序：
void (*Run)(void) = (void (*)(void))RAM_ADDR;
void Main(void)
{ INT32U k ;
INT32U *pulSource = (INT32U*)0x2000,;
INT32U *pulDest = (INT32U*)0x0c000000;
rSYSCFG=CACHECFG;
PortInit();
for(k=0;k<2000> *pulDest++ = *pulSource++;
Run();
}
led程序把两个通用io上连的led作不断的亮和灭：
void Main(void)
{ INT32U k ;
//INT16U *ptr;
rSYSCFG=CACHECFG;
PortInit();
while(1)
{
LedDisp(0);
for(k=0;k LedDisp(3);
for(k=0;k }
}
最后是烧写的程序，详细的代码网上高手们写了不少，我只是给出最简单的实现。烧写时当程序执行到清理完0X0C30_0000到0X0C30_4000的 RAM后，让程序中断下来，通过LOAD MEMORY FORM FILE命令把LOAD.BIN导入0X0C30_0000，LED.BIN导入0X0C30_2000中，继续运行程序直到一个LED亮起，烧写就完成了。拔去仿真器后再上电，可以看到两个LED同时亮灭。
#include option.h
#include 44b.h
#include def.h
//#include romdef.h
//#include stdio.h
//#include stdlib.h

#define FLASH_START_ADDR 0X0000
#define FLASH_ADDR_UNLOCK1 0X5555
#define FLASH_ADDR_UNLOCK2 0X2AAA
#define FLASH_DATA_UNLOCK1 0XAAAA
#define FLASH_DATA_UNLOCK2 0X5555
#define FLASH_DATA_WRITE 0XA0A0
#define FLASH_ERASE 0X8080
#define FLASH_ERASE_SECTOR 0X3030
#define FLASH_ERASE_BLOCK 0X5050
#define FLASH_ERASE_CHIP 0X1010
#define FLASH_SID_QUERY 0X9090
#define FLASH_CFI_QUERY 0X9898
#define FLASH_SID_EXIT 0XF0F0
#define FLASH_OP_TIMEOUT 0Xffff

#define LED_PORTC10 (1 #define LED_PORTC11 (1 #define RAM_ADDR 0xc000000
void (*Run)(void) = (void (*)(void))RAM_ADDR;
void infoFlash(void);
int wait_flash_ready ( INT16U *address, INT16U data );
int writeFlash(INT16U *Address,INT16U Data);
int eraseSector(INT16U* SectorAddr);
int eraseChip(void);

void PortInit(void);
void LedDisp(int LedStatus);

//*****************************************
// FLASH WIRTING
//*****************************************
void Main(void)
{ INT32U k ;
INT16U *pdist,*psrc;
rSYSCFG=CACHECFG;
PortInit();
//infoFlash();
eraseChip();
psrc=(INT16U *)0xc300000;
for(k=0;k<0x4000> *psrc++=0x0; //clear ram
psrc=(INT16U *)0xc300000;
pdist=(INT16U *)0x0;
for(k=0;k<0x4000 k ram to> writeFlash(pdist++,*psrc++);
while(1)
{
LedDisp(0);
for(k=0;k LedDisp(2);
for(k=0;k }
}

//*****************************************
// init the port
//*****************************************
void PortInit(void)
{

rPDATC = 0xffff; //All IO is high
rPCONC = 0x0f55ff54;
rPUPC = 0x3000; //PULL UP RESISTOR should be enabled to I/O
}

//*****************************************
// light led
//*****************************************
void LedDisp(int LedStatus)
{
if((LedStatus&0x01)==0x01)
rPDATC &= (~LED_PORTC10); //LED ON
else
rPDATC |= LED_PORTC10; //LED OFF

if((LedStatus&0x02)==0x02)
rPDATC &=(~LED_PORTC11); //LED ON
else
rPDATC |=LED_PORTC11; //LED OFF
}

//*****************************************
// show the flash soft id
//*****************************************
void infoFlash()
{
int i,j;
INT16U *pFlash;
*((volatile INT16U *)FLASH_START_ADDR)=FLASH_SID_EXIT;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK1)=FLASH_DATA_UNLOCK1;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK2)=FLASH_DATA_UNLOCK2;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK1)=FLASH_SID_QUERY;
for(i=0;i pFlash=FLASH_START_ADDR;
i=0;j=0;
i=(INT16U)*pFlash++;
j=(INT16U)*pFlash;
}
//*****************************************
// erase hold flash
//*****************************************
int eraseChip()
{
*((volatile INT16U *)FLASH_START_ADDR)=FLASH_SID_EXIT;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK1)=FLASH_DATA_UNLOCK1;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK2)=FLASH_DATA_UNLOCK2;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK1)=FLASH_ERASE;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK1)=FLASH_DATA_UNLOCK1;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK2)=FLASH_DATA_UNLOCK2;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK1)=FLASH_ERASE_CHIP;
if( wait_flash_ready((INT16U *)FLASH_START_ADDR,0xffff) )
return 1;
else return 0;
}

//*****************************************
// write one falsh word( 16bit)
//*****************************************
int writeFlash(INT16U *Address,INT16U Data)
{ *((volatile INT16U *)FLASH_START_ADDR)=FLASH_SID_EXIT;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK1)=FLASH_DATA_UNLOCK1;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK2)=FLASH_DATA_UNLOCK2;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK1)=FLASH_DATA_WRITE;
*Address=Data;
if(wait_flash_ready(Address,Data))
return 1;
else return 0;
}

//*****************************************
// wait for operation finish
//*****************************************
int wait_flash_ready ( INT16U *address, INT16U data )
{
INT32U tmp;
INT16U *p;
tmp =0xff;
p=address;
while(((*p)&0x8080)!=(data&0x8080))
{tmp--;
if (tmp==0x0)
return 1; // timeout
}
return 0;
}

, bsp; STRCC r2,[r3],#4
BCC %B2
来看反汇编的代码：
0x0c000ae0: e59f0194 .... LDR r0,0xc000c7c
0x0c000ae4: e59f1194 .... LDR r1,0xc000c80
0x0c000ae8: e59f3194 .1.. LDR r3,0xc000c84
0xc000c7c,开始的三个字的内容是：
0x0c000c7c: 0c000e10 .... DCD 201330192
0x0c000c80: 0c200000 .. . DCD 203423744
0x0c000c84: 0c200000 .. . DCD 203423744
0x0c000c88: 0c200004 .. . DCD 203423748
这些反汇编的代码是一个点led的程序的，可以看出我的小程序代码到0x0c000e10就结束了，0x0c200000是我指定的数据区起始地址。这段程序把|Image$$RO$$Limit| 开始的,长|Image$$ZI$$Base| -|Image$$RW$$Base| 的数据区拷到|Image$$RW$$Base|的对应单元，就是0x0c200000开始的一段ram中。后面还有|Image$$ZI$$ Limit|，在我的代码中是0x0c000c88，内容是0x0c200004.这其实表明我的小程序并没有rw区，只有一个初始为0的变量。
另外还有一段初始化ram控制器的代码：
;****************************************************
;* Set memory control registers
;****************************************************
ldr r0,=SMRDATA
ldmia r0,{r1-r13}
ldr r0,=0x01c80000 ;BWSCON Address
stmia r0,{r1-r13}，
由于44b0x要求13个控制寄存器要一次完成填入，所以先把参数设定在SMRDATA的地址中，一次载入通用寄存器，在一次填入RAM控制寄存器中。 4510的书上介绍调试前需要用SEMEM命令设置这些寄存器，但我自己没有那么做也可以跑的很好，也许是默认已经用了最保守的配置的原因吧！
其余的代码解释比较清晰了，最后摘出我的LED程序和这个小程序的BOOT程序以及烧写程序。这几个程序的project都包括了 44binit.s, option.s, memcfg.s，option.h,44b.h几个从app note中抄来的文件，这里只列了我自己写的主要c代码。其他这些文件我除了把ram和rom的对应配置改了一下外，都没有改动。我的引导程序编译出来是 3k,led程序也是3k,因此我把他们分别定位在rom的0x0和0x2000处，一共写了8k。
LED程序中的44BINTT.S程序功能和LOAD中的44BINTT.S是重复的，主要是我懒得去修改这些汇编，由着他们占用一点时间吧！
load程序负责把从0x20000处开始的4k程序（即led程序）拷到ram 0xc000000中，run函数把pc指到0x0c000000,开始执行led程序：
void (*Run)(void) = (void (*)(void))RAM_ADDR;
void Main(void)
{ INT32U k ;
INT32U *pulSource = (INT32U*)0x2000,;
INT32U *pulDest = (INT32U*)0x0c000000;
rSYSCFG=CACHECFG;
PortInit();
for(k=0;k<2000> *pulDest++ = *pulSource++;
Run();
}
led程序把两个通用io上连的led作不断的亮和灭：
void Main(void)
{ INT32U k ;
//INT16U *ptr;
rSYSCFG=CACHECFG;
PortInit();
while(1)
{
LedDisp(0);
for(k=0;k LedDisp(3);
for(k=0;k }
}
最后是烧写的程序，详细的代码网上高手们写了不少，我只是给出最简单的实现。烧写时当程序执行到清理完0X0C30_0000到0X0C30_4000的 RAM后，让程序中断下来，通过LOAD MEMORY FORM FILE命令把LOAD.BIN导入0X0C30_0000，LED.BIN导入0X0C30_2000中，继续运行程序直到一个LED亮起，烧写就完成了。拔去仿真器后再上电，可以看到两个LED同时亮灭。
#include option.h
#include 44b.h
#include def.h
//#include romdef.h
//#include stdio.h
//#include stdlib.h

#define FLASH_START_ADDR 0X0000
#define FLASH_ADDR_UNLOCK1 0X5555
#define FLASH_ADDR_UNLOCK2 0X2AAA
#define FLASH_DATA_UNLOCK1 0XAAAA
#define FLASH_DATA_UNLOCK2 0X5555
#define FLASH_DATA_WRITE 0XA0A0
#define FLASH_ERASE 0X8080
#define FLASH_ERASE_SECTOR 0X3030
#define FLASH_ERASE_BLOCK 0X5050
#define FLASH_ERASE_CHIP 0X1010
#define FLASH_SID_QUERY 0X9090
#define FLASH_CFI_QUERY 0X9898
#define FLASH_SID_EXIT 0XF0F0
#define FLASH_OP_TIMEOUT 0Xffff

#define LED_PORTC10 (1 #define LED_PORTC11 (1 #define RAM_ADDR 0xc000000
void (*Run)(void) = (void (*)(void))RAM_ADDR;
void infoFlash(void);
int wait_flash_ready ( INT16U *address, INT16U data );
int writeFlash(INT16U *Address,INT16U Data);
int eraseSector(INT16U* SectorAddr);
int eraseChip(void);

void PortInit(void);
void LedDisp(int LedStatus);

//*****************************************
// FLASH WIRTING
//*****************************************
void Main(void)
{ INT32U k ;
INT16U *pdist,*psrc;
rSYSCFG=CACHECFG;
PortInit();
//infoFlash();
eraseChip();
psrc=(INT16U *)0xc300000;
for(k=0;k<0x4000> *psrc++=0x0; //clear ram
psrc=(INT16U *)0xc300000;
pdist=(INT16U *)0x0;
for(k=0;k<0x4000 k ram to> writeFlash(pdist++,*psrc++);
while(1)
{
LedDisp(0);
for(k=0;k LedDisp(2);
for(k=0;k }
}

//*****************************************
// init the port
//*****************************************
void PortInit(void)
{

rPDATC = 0xffff; //All IO is high
rPCONC = 0x0f55ff54;
rPUPC = 0x3000; //PULL UP RESISTOR should be enabled to I/O
}

//*****************************************
// light led
//*****************************************
void LedDisp(int LedStatus)
{
if((LedStatus&0x01)==0x01)
rPDATC &= (~LED_PORTC10); //LED ON
else
rPDATC |= LED_PORTC10; //LED OFF

if((LedStatus&0x02)==0x02)
rPDATC &=(~LED_PORTC11); //LED ON
else
rPDATC |=LED_PORTC11; //LED OFF
}

//*****************************************
// show the flash soft id
//*****************************************
void infoFlash()
{
int i,j;
INT16U *pFlash;
*((volatile INT16U *)FLASH_START_ADDR)=FLASH_SID_EXIT;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK1)=FLASH_DATA_UNLOCK1;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK2)=FLASH_DATA_UNLOCK2;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK1)=FLASH_SID_QUERY;
for(i=0;i pFlash=FLASH_START_ADDR;
i=0;j=0;
i=(INT16U)*pFlash++;
j=(INT16U)*pFlash;
}
//*****************************************
// erase hold flash
//*****************************************
int eraseChip()
{
*((volatile INT16U *)FLASH_START_ADDR)=FLASH_SID_EXIT;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK1)=FLASH_DATA_UNLOCK1;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK2)=FLASH_DATA_UNLOCK2;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK1)=FLASH_ERASE;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK1)=FLASH_DATA_UNLOCK1;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK2)=FLASH_DATA_UNLOCK2;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK1)=FLASH_ERASE_CHIP;
if( wait_flash_ready((INT16U *)FLASH_START_ADDR,0xffff) )
return 1;
else return 0;
}

//*****************************************
// write one falsh word( 16bit)
//*****************************************
int writeFlash(INT16U *Address,INT16U Data)
{ *((volatile INT16U *)FLASH_START_ADDR)=FLASH_SID_EXIT;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK1)=FLASH_DATA_UNLOCK1;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK2)=FLASH_DATA_UNLOCK2;
*((volatile INT16U *)FLASH_START_ADDR+FLASH_ADDR_UNLOCK1)=FLASH_DATA_WRITE;
*Address=Data;
if(wait_flash_ready(Address,Data))
return 1;
else return 0;
}

//*****************************************
// wait for operation finish
//*****************************************
int wait_flash_ready ( INT16U *address, INT16U data )
{
INT32U tmp;
INT16U *p;
tmp =0xff;
p=address;
while(((*p)&0x8080)!=(data&0x8080))
{tmp--;
if (tmp==0x0)
return 1; // timeout
}
return 0;
}

上一篇：玩转Linux文件系统加密下一篇：2410启动代码分析

我要评论